max80_fw/esp32/sysvars.pl

#!/usr/bin/perl
use strict;
use integer;
use File::Basename;

sub c_name($) {
    my($s) = @_;

    $s =~ s/[^A-Za-z0-9_]+/_/g;
    return $s;
}

die "Usage: $0 infile hfile cfile\n" unless (scalar @ARGV >= 3);

my($infile, $hfile, $cfile) = @ARGV;

my $err = 0;

open(my $in, '<', $infile) or die "$0: $infile: $!\n";
my $ns;
my %vars;
my %nsprefix;

my $line = 0;
while (defined(my $l = <$in>)) {
    $line++;
    $l =~ s/^\s+//;
    $l =~ s/\s+$//;
    next if ($l =~ /^(\#.*)?$/);
    if ($l =~ /^\@(\w+)(\s+([\w\.]+))?/) {
	$ns = $1;
	if (!defined($vars{$ns})) {
	    $vars{$ns} = {};
	}
	$nsprefix{$ns} = $3;
	next;
    }

    if (!defined{$ns}) {
	print STDERR "$0:$infile:$line: variable without namespace\n";
	$err++;
	next;
    }

    my($var,$type,$defval) = split(/\s+/, $l);
    if (!defined($type)) {
	print STDERR "$0:$infile:$line: variable $var lacks type\n";
	$err++;
	next;
    }
    $vars{$ns}->{$var} = [$type, $defval];
}

close($in);

exit 1 if ($err);

my @nslist = sort keys(%vars);
my %nsfirst;
my %nscount;
my @varname = (undef);
my @varenum = ('sysvar_null');
my @vartype = ("\t[sysvar_null] = SYSVAR_TYPE(nulltype),\n");
my @vardef;

my $cnt = 1;
foreach my $ns (@nslist) {
    $nsfirst{$ns} = $cnt;
    foreach my $var (sort keys(%{$vars{$ns}})) {
	my($type, $defval) = @{$vars{$ns}->{$var}};
	push(@varname, $nsprefix{$ns}.$var);

	my $ename = c_name($ns.'.'.$var);
	push(@varenum, $ename);

	push(@vartype, "\t[$ename] = SYSVAR_TYPE($type),\n");
	if (defined($defval)) {
	    # Add mangling here if needed
	    push(@vardef, "\t[$ename] = { .v_$type = $defval },\n");
	}
	$cnt++;
    }
    $nscount{$ns} = $cnt - $nsfirst{$ns};
}

open(my $h, '>', $hfile) or die "$0:$hfile: $!\n";
my $htag = c_name(uc(basename($hfile)));
print $h "#ifndef $htag\n";
print $h "#define $htag\n\n";

print $h "#include \"sysvar_common.h\"\n\n";

print $h "enum sysvar_ns {\n";
print $h map { "\tsysvar_ns_$_,\n" } @nslist;
print $h "\tsysvar_nscount\n};\n\n";

print $h "enum sysvars {\n";
print $h map { "\t$_,\n" } @varenum;
print $h "\tsysvar_count\n};\n\n";

push(@varenum, 'sysvar_count');

foreach my $ns (@nslist) {
    print $h "#define sysvar_ns_${ns}_start ", $varenum[$nsfirst{$ns}], "\n";
    print $h "#define sysvar_ns_${ns}_end   ", $varenum[$nsfirst{$ns}+$nscount{$ns}], "\n";
    print $h "#define sysvar_ns_${ns}_count ", $nscount{$ns}, "\n";
}

print $h "\n";
print $h "extern const char * const sysvar_name[$cnt];\n";
print $h "extern const sysvar_type_t sysvar_type[$cnt];\n";
print $h "extern const sysvar_t sysvar_defval[$cnt];\n";
print $h "extern sysvar_t sysvar_val[$cnt];\n";
print $h "extern bool sysvar_isset[$cnt];\n";

print $h "\n#endif /* $htag */\n";
close($h);

open(my $c, '>', $cfile) or die "$0:$cfile: $!\n";
print $c "#include <stddef.h>\n";
print $c "#include \"", basename($hfile), "\"\n\n";

print $c "const char * const sysvar_name[$cnt] = {\n";
print $c "\tNULL,\n";
foreach my $ns (@nslist) {
    print $c "\n\t/* ---- $ns ---- */\n";
    my $v_end = $nsfirst{$ns} + $nscount{$ns};
    for (my $v = $nsfirst{$ns}; $v < $v_end; $v++) {
	print $c "\t\"", $varname[$v], "\",\n";
    }
}
print $c "};\n";

print $c "const sysvar_type_t sysvar_type[$cnt] = {\n";
print $c @vartype;
print $c "};\n";

print $c "const sysvar_t sysvar_defval[$cnt] = {\n";
print $c @vardef;
print $c "};\n";

print $c "sysvar_t sysvar_val[$cnt];\n";
print $c "bool sysvar_isset[$cnt];\n";
close($c);