esp32S2-usb-host-library/examples/cdc/cdc.ino

#include "cdchost.h"
#define DEVICE_ADDRESS 2
USBHostCDC port(DEVICE_ADDRESS);

void ctrl_pipe_cb(usb_host_even_t event, void *data)
{
  Serial.printf("CTRL EVENT: 0x%x\n", event);
}

void port_cb(port_event_msg_t msg, USBHostPort* port)
{
  Serial.printf("PORT EVENT: 0x%x\n", msg.port_event);
}

void cdc_datain_cb(usb_host_even_t event, void *data)
{
  usb_irp_t *irp = (usb_irp_t *)data;
  Serial.printf("IN EVENT: 0x%x, buffer_len: %d, received: %d\n", event, irp->num_bytes, irp->actual_num_bytes);
  Serial.print("DATA: ");
  for (size_t i = 0; i < irp->actual_num_bytes; i++)
  {
    Serial.printf("%c", irp->data_buffer[i]);
  }
  Serial.println();
}

void cdc_dataout_cb(usb_host_even_t event, void *data)
{
  usb_irp_t *irp = (usb_irp_t *)data;
  Serial.printf("OUT EVENT: 0x%x, buffer_len: %d, sent: %d\n", event, irp->num_bytes, irp->actual_num_bytes);
  Serial.print("DATA: ");
  for (size_t i = 0; i < irp->actual_num_bytes; i++)
  {
    Serial.printf("%c", irp->data_buffer[i]);
  }
  Serial.println();
}

void setup()
{
  Serial.begin(115200);
  port.init();
  port.onPortEvent(port_cb);
  port.onControlEvent(ctrl_pipe_cb);
  port.onDataIn(cdc_datain_cb);
  port.onDataOut(cdc_dataout_cb);
}

void loop()
{
  delay(10);
  while (Serial.available())
  {
    size_t l = Serial.available();
    uint8_t b[l];
    l = Serial.read(b, l);
    port.sendData(b, l);
  }
}